net-misc/nextcloud-client/nextcloud-client-3.1.1-r100.ebuild

   1 # Copyright 1999-2021 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cmake xdg
   7
   8 DESCRIPTION="Desktop Syncing Client for Nextcloud"
   9 HOMEPAGE="https://github.com/nextcloud/desktop"
  10 SRC_URI="https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="CC-BY-3.0 GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~arm64 ~x86"
  15 IUSE="doc dolphin libressl nautilus test +webflow"
  16
  17 COMMON_DEPEND=">=dev-db/sqlite-3.4:3
  18         dev-libs/qtkeychain[gnome-keyring,qt5(+)]
  19         dev-qt/qtconcurrent:5
  20         dev-qt/qtcore:5
  21         dev-qt/qtdbus:5
  22         dev-qt/qtdeclarative:5
  23         dev-qt/qtgui:5
  24         dev-qt/qtnetwork:5[ssl]
  25         dev-qt/qtquickcontrols2:5
  26         dev-qt/qtsql:5
  27         dev-qt/qtsvg:5
  28         dev-qt/qtwidgets:5
  29         dev-qt/qtxml:5
  30         sys-fs/inotify-tools
  31         dolphin? (
  32                 kde-frameworks/kcoreaddons:5
  33                 kde-frameworks/kio:5
  34         )
  35         !libressl? ( >=dev-libs/openssl-1.1.0:0= )
  36         libressl? ( >=dev-libs/libressl-3.1:0= )
  37         nautilus? ( dev-python/nautilus-python )
  38         webflow? ( dev-qt/qtwebengine:5[widgets] )"
  39
  40 RDEPEND="${COMMON_DEPEND}"
  41 DEPEND="${COMMON_DEPEND}
  42         dev-qt/linguist-tools:5
  43         doc? (
  44                 dev-python/sphinx
  45                 dev-tex/latexmk
  46                 dev-texlive/texlive-latexextra
  47                 virtual/latex-base
  48         )
  49         dolphin? ( kde-frameworks/extra-cmake-modules )
  50         test? (
  51                 dev-util/cmocka
  52                 dev-qt/qttest:5
  53         )"
  54
  55 RESTRICT="!test? ( test )"
  56
  57 S=${WORKDIR}/desktop-${PV/_/-}
  58
  59 src_prepare() {
  60         # Keep tests in ${T}
  61         sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
  62
  63         if ! use webflow; then
  64                 eapply "${FILESDIR}/v3.1.1-nowebengine.patch"
  65         fi
  66
  67         if ! use nautilus; then
  68                 pushd shell_integration > /dev/null || die
  69                 cmake_comment_add_subdirectory nautilus
  70                 popd > /dev/null || die
  71         fi
  72         cmake_src_prepare
  73 }
  74
  75 src_configure() {
  76         local mycmakeargs=(
  77                 -DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
  78                 -DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
  79                 -DCMAKE_DISABLE_FIND_PACKAGE_Sphinx=$(usex !doc)
  80                 -DCMAKE_DISABLE_FIND_PACKAGE_KF5=$(usex !dolphin)
  81                 -DNO_WEBENGINE=$(usex !webflow)
  82                 -DNO_SHIBBOLETH=yes
  83                 -DUNIT_TESTING=$(usex test)
  84         )
  85
  86         cmake_src_configure
  87 }
  88
  89 pkg_postinst() {
  90         xdg_pkg_postinst
  91         if ! use doc ; then
  92                 elog "Documentation and man pages not installed"
  93                 elog "Enable doc USE-flag to generate them"
  94         fi
  95 }