app-pda/libimobiledevice: Sync with portage
authorStefan Huber <shuber@sthu.org>
Thu, 14 May 2020 08:23:28 +0000 (10:23 +0200)
committerStefan Huber <shuber@sthu.org>
Thu, 14 May 2020 08:23:28 +0000 (10:23 +0200)
Merge with portage version of ebuild, which switches to EAPI=7.

app-pda/libimobiledevice/Manifest
app-pda/libimobiledevice/libimobiledevice-9999.ebuild

index a30b7f0..768eb50 100644 (file)
@@ -1,2 +1,2 @@
-DIST libimobiledevice.zip 368646 SHA256 537a1a908f4ee41c433293eeec029c314ce217878d39424c9ce266b4db4b9f3b SHA512 395055f3fa05c52cc1a7c2df1751a3fc35db20d72a812bc93b37ed4e77359ce24d4ca3321c92594eb7b9d78bc483584fbd6121a82563aef51b93d90059171955 WHIRLPOOL 4885b1402b7fb68d78e2b4460bc923e9b5a099cee2fbae1bd2b4ad823f8b9f6045d453c213911d6abe730f9deaff4e2e82f9e43e70bade861d55d17a7970d42f
-EBUILD libimobiledevice-9999.ebuild 2538 SHA256 5a4e3bf3cc7b6c01468730412ac6add7f5a75ccb16f50c726c93364e4a7495e5 SHA512 9c775dbc97064d2ec0459a1d0da264e68ccfada8205c2940e71910b742f33f893fc1bb0d9346e7d1fcf0e0caf02943bea73689758db33300e0afb24db8502837 WHIRLPOOL bab85c9cb508b9b2bdf553fab5faa283e26462caebaa4c5e62c6917319c26311812ab134f5495d4cce00ebc2feb988cdc7333281998a45d61008edb927a55a35
+DIST libimobiledevice-9999.tar.bz2 197991 BLAKE2B 9e534c239a46c772042a7f017f1fd38f8797eab667d26abe4775a788783007edbce6bab83f060e10b196b01489765b8cb7c19f60468080d0a3093b41eb461bf9 SHA512 0ea6a5353a020ebbe5bcbb898dca081a5646436b85c9af6e938a1529b6005203c2da3aeacfcae114e78a623cc3168aff4b4e2dd12d987a49ff41dcdd33c1bcf9
+EBUILD libimobiledevice-9999.ebuild 2565 BLAKE2B 25fa49e3c6853371088b11f8c8d65e4a76d9c1c3b75b902d4f6a37e7df41c4186d90a43d467b456777e75014175f299c9c707b6f49ce50863f4a15580f494fcb SHA512 9c011a8c1dc9aa51c8f43828e12dc7aca6de251734c02fc979c31e15b2394a1f0e16de497359fb0b32add8b952cc9a275d6e4af3aeaf1f65890d20937c67f8b1
index faad857..1bfc0d5 100644 (file)
@@ -1,45 +1,56 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-PYTHON_COMPAT=( python{2_7,3_4,3_5} )
-inherit eutils autotools python-r1
+EAPI=7
+
+COMMIT="master"
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit autotools python-r1
 
 DESCRIPTION="Support library to communicate with Apple iPhone/iPod Touch devices"
-HOMEPAGE="http://www.libimobiledevice.org/"
-SRC_URI="https://github.com/${PN}/${PN}/archive/master.zip -> ${PN}.zip"
+HOMEPAGE="https://www.libimobiledevice.org/"
+SRC_URI="https://cgit.libimobiledevice.org/libimobiledevice.git/snapshot/libimobiledevice-${COMMIT}.tar.bz2 -> ${P}.tar.bz2"
 
 # While COPYING* doesn't mention 'or any later version', all the headers do, hence use +
 LICENSE="GPL-2+ LGPL-2.1+"
+
 SLOT="0/6" # based on SONAME of libimobiledevice.so
+
 KEYWORDS="amd64 ~arm ~arm64 ppc ~ppc64 x86"
-IUSE="gnutls python static-libs"
+IUSE="doc gnutls libressl python static-libs"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
 
-RDEPEND=">=app-pda/libplist-1.11:=
-       >=app-pda/libusbmuxd-1.0.9:=
+RDEPEND="
+       >=app-pda/libplist-1.11:=
+       >=app-pda/libusbmuxd-1.1.0:=
        gnutls? (
                dev-libs/libgcrypt:0
                >=dev-libs/libtasn1-1.1
-               >=net-libs/gnutls-2.2.0
-               )
-       !gnutls? ( dev-libs/openssl:0 )
+               >=net-libs/gnutls-2.2.0 )
+       !gnutls? (
+               !libressl? ( dev-libs/openssl:0= )
+               libressl? ( dev-libs/libressl:0= ) )
        python? (
                ${PYTHON_DEPS}
-               app-pda/libplist[python(-),${PYTHON_USEDEP}]
-               )"
-DEPEND="${RDEPEND}
-       virtual/pkgconfig
-       python? ( >=dev-python/cython-0.17[${PYTHON_USEDEP}] )"
+               app-pda/libplist[python(-),${PYTHON_USEDEP}] )
+"
 
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+DEPEND="
+       ${RDEPEND}
+"
 
-DOCS=( AUTHORS NEWS README )
+BDEPEND="
+       virtual/pkgconfig
+       doc? ( app-doc/doxygen )
+       python? ( >=dev-python/cython-0.17[${PYTHON_USEDEP}] )
+"
 
+S="${WORKDIR}/${PN}-${COMMIT}"
 BUILD_DIR="${S}_build"
-S="${WORKDIR}/${PN}-master"
 
 src_prepare() {
-       #epatch "${FILESDIR}/gnutls-3.4.patch"
+       default
        eautoreconf
 }
 
@@ -58,7 +69,8 @@ src_configure() {
 
        do_configure_python() {
                # Bug 567916
-               PYTHON_LDFLAGS="$(python_get_LIBS)" do_configure "$@"
+               local -x PYTHON_LDFLAGS="$(python_get_LIBS)"
+               do_configure "$@"
        }
 
        do_configure --without-cython
@@ -67,35 +79,34 @@ src_configure() {
 
 src_compile() {
        python_compile() {
-               emake -C "${BUILD_DIR}"/cython -j1 \
-                       VPATH="${S}/cython:${native_builddir}/cython" \
-                       imobiledevice_la_LIBADD="${native_builddir}/src/libimobiledevice.la"
+               emake -C "${BUILD_DIR}"/cython \
+                       VPATH="${S}/cython:$1/cython" \
+                       imobiledevice_la_LIBADD="$1/src/libimobiledevice.la"
        }
 
-       local native_builddir=${BUILD_DIR}
-       pushd "${BUILD_DIR}" >/dev/null || die
-       emake -j1
-       use python && python_foreach_impl python_compile
-       popd >/dev/null || die
+       emake -C "${BUILD_DIR}"
+       use python && python_foreach_impl python_compile "${BUILD_DIR}"
+
+       if use doc; then
+               doxygen "${BUILD_DIR}"/doxygen.cfg || die
+       fi
 }
 
 src_install() {
        python_install() {
-               emake -C "${BUILD_DIR}/cython" -j1 \
-                       VPATH="${S}/cython:${native_builddir}/cython" \
-                       DESTDIR="${D}" install
+               emake -C "${BUILD_DIR}/cython" install \
+                       DESTDIR="${D}" \
+                       VPATH="${S}/cython:$1/cython"
        }
 
-       local native_builddir=${BUILD_DIR}
-       pushd "${BUILD_DIR}" >/dev/null || die
-       emake -j1 DESTDIR="${D}" install
-       use python && python_foreach_impl python_install
-       popd >/dev/null || die
+       emake -C "${BUILD_DIR}" install DESTDIR="${D}"
+       use python && python_foreach_impl python_install "${BUILD_DIR}"
+       use doc && dodoc docs/html/*
 
-       #dodoc docs/html/*
        if use python; then
                insinto /usr/include/${PN}/cython
                doins cython/imobiledevice.pxd
        fi
-       prune_libtool_files --all
+
+       find "${D}" -name '*.la' -delete || die
 }