media-gfx/ipe/ipe-7.1.4.ebuild

   1 # Distributed under the terms of the GNU General Public License v2
   2 # $Header: $
   3
   4 EAPI=4
   5 inherit eutils toolchain-funcs qt4-r2
   6
   7 DESCRIPTION="Drawing editor for creating figures in PDF or PS formats"
   8 HOMEPAGE="http://ipe7.sourceforge.net/"
   9 SRC_URI="mirror://sourceforge/ipe7/${PN}/7.1.0/${P}-src.tar.gz"
  10
  11 LICENSE="GPL-3"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="highprec"
  15
  16 RDEPEND="app-text/texlive-core
  17         >=dev-lang/lua-5.2
  18         media-libs/freetype:2
  19         x11-libs/cairo
  20         dev-qt/qtcore:4
  21         dev-qt/qtgui:4"
  22 DEPEND="${RDEPEND}
  23         virtual/pkgconfig"
  24
  25 S="${WORKDIR}/${P}/src"
  26 COMMONDIR=/usr/share/ipe/common
  27
  28 search_urw_fonts() {
  29         # colon-separated list of paths
  30         local texmfdist="$(kpsewhich -var-value=TEXMFDIST)"
  31         # according to TeX directory structure
  32         local urwdir=fonts/type1/urw
  33         # add colon as field separator
  34         local IFS="${IFS}:" dir
  35         for dir in ${texmfdist}; do
  36                 if [[ -d ${dir}/${urwdir} ]]; then
  37                         URWFONTDIR="${dir}/${urwdir}"
  38                         return 0
  39                 fi
  40         done
  41         return 1
  42 }
  43
  44 src_prepare() {
  45         sed -i \
  46                 -e 's/fpic/fPIC/' \
  47                 -e 's/moc-qt4/moc/' \
  48                 -e "s:\$(IPEPREFIX)/lib:\$(IPEPREFIX)/$(get_libdir):g" \
  49                 config.mak || die
  50         sed -i -e 's/install -s/install/' common.mak || die
  51
  52         if use highprec; then
  53                 einfo "Adding patch for higher output precision"
  54                 epatch "${FILESDIR}"/${PN}-outputprecision.patch
  55         fi
  56         epatch "${FILESDIR}"/0001-config.mak-use-correct-lua-package-name.patch
  57         epatch "${FILESDIR}"/0002-config.mak-Add-ldl-flag.patch
  58 }
  59
  60 pkg_setup() {
  61         if search_urw_fonts; then
  62                 einfo "URW fonts found in ${URWFONTDIR}"
  63         else
  64                 ewarn "Could not find directory containing URW fonts"
  65                 ewarn "Ipe will not function properly without them."
  66         fi
  67 }
  68
  69 src_compile() {
  70         emake \
  71                 CXX=$(tc-getCXX) \
  72                 IPEPREFIX="${EPREFIX}/usr" \
  73                 IPEDOCDIR="${EPREFIX}/usr/share/doc/${PF}/html"
  74 }
  75
  76 src_install() {
  77         emake install \
  78                 IPEPREFIX="${EPREFIX}/usr" \
  79                 IPEDOCDIR="${EPREFIX}/usr/share/doc/${PF}/html" \
  80                 INSTALL_ROOT="${ED}"
  81         dodoc ../{news,readme}.txt
  82         doicon ipe/icons/ipe.png
  83         make_desktop_entry ipe Ipe ipe
  84         # Link style sheets
  85         if [ -d $COMMONDIR/styles ]; then
  86                 einfo "Linking common style sheets from $COMMONDIR"
  87                 for f in $COMMONDIR/styles/*; do
  88                         einfo "  Linking ${f##*/}"
  89                         dosym $f usr/share/ipe/${PV}/styles/${f##*/}
  90                 done
  91
  92                 elog "Style sheets from $COMMONDIR/styles have been symlinked to"
  93                 elog "the style sheet directory of ${P}. If you add additional"
  94                 elog "style sheets later to $COMMONDIR/styles you may symlink"
  95                 elog "them by hand to '/usr/share/ipe/${PV}/styles/'."
  96         fi
  97 }