app-misc/khard/khard-0.16.1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python3_{6,7} )
   6 DISTUTILS_USE_SETUPTOOLS=rdepend
   7
   8 inherit distutils-r1
   9
  10 DESCRIPTION="Console CardDAV client"
  11 HOMEPAGE="https://github.com/scheibler/khard"
  12 LICENSE="GPL-3"
  13 SLOT="0"
  14 IUSE="test zsh-completion"
  15 RESTRICT="!test? ( test )"
  16
  17 if [ "${PV}" == "9999" ]; then
  18         inherit git-r3
  19         EGIT_REPO_URI="https://github.com/scheibler/khard"
  20 else
  21         SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
  22         KEYWORDS="amd64 ~arm64 ~x86"
  23 fi
  24
  25 RDEPEND="
  26         dev-python/atomicwrites[${PYTHON_USEDEP}]
  27         dev-python/configobj[${PYTHON_USEDEP}]
  28         dev-python/ruamel-yaml[${PYTHON_USEDEP}]
  29         dev-python/unidecode[${PYTHON_USEDEP}]
  30         >dev-python/vobject-0.9.3[${PYTHON_USEDEP}]
  31 "
  32 DEPEND="
  33         dev-python/setuptools[${PYTHON_USEDEP}]
  34         test? (
  35                 ${RDEPEND}
  36         )
  37 "
  38 # vobject-0.9.3 breaks khard, see
  39 # https://github.com/scheibler/khard/issues/87
  40 # https://github.com/eventable/vobject/issues/39
  41
  42 DOCS=( CHANGES README.md doc/source/examples/khard.conf.example )
  43
  44 src_install() {
  45         distutils-r1_src_install
  46
  47         if use zsh-completion; then
  48                 insinto /usr/share/zsh/site-functions
  49                 doins misc/zsh/_khard
  50         fi
  51 }
  52
  53 python_test() {
  54         esetup.py test
  55 }