gpgsigs/gpgsigs

   1 #!/usr/bin/perl
   2
   3 # $Id$
   4
   5 # See the pod documentation at the end of this file for author,
   6 # copyright, and licence information.
   7 #
   8 # Depends:
   9 #          libintl-perl (Locale::Recode)
  10 #       OR libtext-iconv-perl (Text::Iconv),
  11 #       OR the "recode" binary
  12 #
  13 # Changelog:
  14 # 0.1
  15 # 0.2 2005-05-14 cb:
  16 #   * use the user's normal keyring to find signatures
  17 #   * support for multiple user keys
  18 #   * better charset conversion
  19 #   * pod documentation
  20
  21 my $VERSION = qq$Rev$;
  22
  23 use strict;
  24 use warnings;
  25 use English;
  26 use IPC::Open3;
  27 use Getopt::Long;
  28
  29
  30 sub version($)
  31 {
  32         my ($fd) = @_;
  33
  34         print $fd <<EOF;
  35 gpgsigs $VERSION- http://pgp-tools.alioth.debian.org/
  36   (c) 2004 Uli Martens <uli\@youam.net>
  37   (c) 2004, 2005 Peter Palfrader <peter\@palfrader.org>
  38   (c) 2004, 2005 Christoph Berg <cb\@df7cb.de>
  39 EOF
  40 }
  41
  42 sub usage($$)
  43 {
  44         my ($fd, $error) = @_;
  45
  46         version($fd);
  47         print $fd <<EOF;
  48
  49 Usage: $PROGRAM_NAME [-r] [-t <charset>] <keyid> <keytxt> [<outfile>]
  50
  51 keyid is a long or short keyid (e.g. DE7AAF6E94C09C7F or 94C09C7F)
  52 separate multiple keyids with ','
  53 -r            call gpg --recv-keys before proceeding
  54 -f <charset>  convert <keytxt> from charset
  55 -t <charset>  convert UIDs to charset in output
  56 EOF
  57         exit $error;
  58 }
  59
  60
  61 my ($fromcharset, $charset, $recv_keys);
  62 Getopt::Long::config('bundling');
  63 GetOptions(
  64         '-f=s' => \$fromcharset,
  65         '-t=s' => \$charset,
  66         r => \$recv_keys,
  67         help => sub { usage(*STDOUT, 0); },
  68         version => sub { version(*STDOUT); exit 0;},
  69 ) or usage(*STDERR, 1);
  70
  71
  72 # charset conversion
  73 $fromcharset ||= "ISO-8859-1";
  74 $charset ||= $ENV{LC_ALL} || $ENV{LC_CTYPE} || $ENV{LANG} || "ISO-8859-1";
  75 $charset = "ISO-8859-1" unless $charset =~ /[\.-]/;
  76 $charset =~ s/.*\.//;
  77 $charset =~ s/@.*//;
  78
  79 my ($rf, $rt, $if, $it);
  80 if (eval "require Locale::Recode") {
  81         $rf = Locale::Recode->new (from => $fromcharset, to => $charset) if $fromcharset;
  82         $rt = Locale::Recode->new (from => 'UTF-8', to => $charset);
  83 } elsif (eval "require Text::Iconv") {
  84         $if = Text::Iconv->new($fromcharset, $charset) if $fromcharset;
  85         $it = Text::Iconv->new("UTF-8", $charset);
  86 }
  87
  88 sub myfromrecode($) {
  89         my ($text) = @_;
  90         if (defined $rf) {
  91                 my $orig = $text;
  92                 $rf->recode($text);
  93                 return $text;
  94         } elsif (defined $if) {
  95                 return $if->convert($text);
  96         } else {
  97                 my $pid = open3(\*WTRFH, \*RDRFH, \*ERRFH, 'recode', "$fromcharset..$charset");
  98                 print WTRFH $text;
  99                 close WTRFH;
 100                 local $/ = undef;
 101                 my $result = <RDRFH>;
 102                 close RDRFH;
 103                 close ERRFH;
 104                 waitpid $pid, 0;
 105                 die ("'recode' failed, is it installed?\n") unless defined $result;
 106                 return $result;
 107         }
 108 }
 109
 110 sub myrecode($) {
 111         my ($text) = @_;
 112         if (defined $rt) {
 113                 my $orig = $text;
 114                 $rt->recode($text);
 115                 return $text;
 116         } elsif (defined $it) {
 117                 my $result = $it->convert($text);
 118                 warn ("Could not convert '$text'\n") unless defined $result;
 119                 return (defined $result) ? $result : $text
 120         } else {
 121                 my $pid = open3(\*WTRFH, \*RDRFH, \*ERRFH, 'recode', "utf8..$charset");
 122                 print WTRFH $text;
 123                 close WTRFH;
 124                 local $/ = undef;
 125                 my $result = <RDRFH>;
 126                 close RDRFH;
 127                 close ERRFH;
 128                 waitpid $pid, 0;
 129                 warn ("'recode' failed, is it installed?\n") unless defined $result;
 130                 return (defined $result) ? $result : $text
 131         }
 132 }
 133
 134
 135 # parse options
 136 my $mykey = uc(shift @ARGV);
 137 my $keytxt = (shift @ARGV) || usage(*STDERR, 1);
 138 my $outfile = (shift @ARGV) || '-';
 139
 140 my @mykeys = split /,/, $mykey;
 141 map { s/^0x//i; } @mykeys;
 142
 143 if (!@mykeys || scalar @ARGV) {
 144         usage(*STDERR, 1);
 145 }
 146 foreach my $falsekey (grep { $_ !~ /^([0-9A-F]{16,16}|[0-9A-F]{8,8})$/ } @mykeys) {
 147         print STDERR "Invalid keyid $falsekey given\n";
 148         usage(*STDERR, 1);
 149 }
 150
 151 -r $keytxt or die ("$keytxt does not exist\n");
 152
 153
 154 # get list of keys in file
 155 my @keys;
 156 open (TXT, $keytxt) or die ("Cannot open $keytxt\n");
 157 while (<TXT>) {
 158         if ( m/^pub  +(?:\d+)[DR]\/([0-9A-F]{8}) [0-9]{4}-[0-9]{2}-[0-9]{2} *(.*)/ ) {
 159                 push @keys, $1;
 160         }
 161 }
 162 close TXT;
 163
 164
 165 # get all known signatures
 166 if ($recv_keys) {
 167         print STDERR "Requesting keys from keyserver\n";
 168         system "gpg --recv-keys @keys";
 169 }
 170
 171 print STDERR "Running --list-sigs, this will take a while ";
 172 open SIGS, "gpg --fixed-list-mode --with-colons --list-sigs @keys 2>/dev/null |"
 173         or die "can't get gpg listing";
 174
 175 my ($key, $uid, $sigs);
 176 while (<SIGS>) {
 177         if ( m/^pub:(?:.*?:){3,3}([0-9A-F]{16,16}):/ ) {
 178                 $key = $1;
 179                 print STDERR ".";
 180                 next;
 181         }
 182         if ( m/^uid:(?:.*?:){8,8}(.*):/s ) {
 183                 $uid = myrecode($1);
 184                 next;
 185         }
 186         if ( m/^sig:(?:.*?:){3,3}([0-9A-F]{8})([0-9A-F]{8}):(?:.*?:){5,5}(.*?):/ ) {
 187                 my $class = $3;
 188                 if ($class eq '10x') {
 189                         $class = 'S';
 190                 } elsif ($class eq '11x') {
 191                         $class = '1';
 192                 } elsif ($class eq '12x') {
 193                         $class = '2';
 194                 } elsif ($class eq '13x') {
 195                         $class = '3';
 196                 } else {
 197                         $class = 's';
 198                 };
 199                 # Handle the case where one UID was signed multiple times
 200                 # with different signature classes.
 201                 my $before = $sigs->{$key}->{$uid}->{$1.$2};
 202                 if (defined $before) {
 203                         if ($before eq 'S' || $before eq 's') {
 204                                 $sigs->{$key}->{$uid}->{$1.$2} = $class;
 205                         } elsif ($before < $class) {
 206                                 $sigs->{$key}->{$uid}->{$1.$2} = $class;
 207                         };
 208                 } else {
 209                         $sigs->{$key}->{$uid}->{$1.$2} .= $class;
 210                 };
 211                 $sigs->{$key}->{$uid}->{$2} = $sigs->{$key}->{$uid}->{$1.$2}
 212                 next;
 213         }
 214         if ( m/^uat:/ ) {
 215                 $uid = "Photo ID";
 216                 next;
 217         }
 218         next if ( m/^(rev|sub|tru):/ );
 219         warn "unknown value: '$_', key: ".(defined $key ? $key :'none')."\n";
 220 }
 221 close SIGS;
 222 print STDERR "\n";
 223
 224 for my $k ( keys %{$sigs} ) {
 225         if ( $k =~ m/^[0-9A-F]{8}([0-9A-F]{8})$/ ) {
 226                 $sigs->{$1} = $sigs->{$k};
 227         }
 228 }
 229
 230
 231 # read checksums
 232 open MD, "gpg --print-md md5 $keytxt|" or warn "can't get gpg md5\n";
 233 my $MD5 = <MD>;
 234 close MD;
 235 open MD, "gpg --print-md sha1 $keytxt|" or warn "can't get gpg sha1\n";
 236 my $SHA1 = <MD>;
 237 close MD;
 238
 239 chomp $MD5;
 240 chomp $SHA1;
 241 my $metatxt = quotemeta($keytxt);
 242 $MD5 =~ s/^$metatxt:\s*//;
 243 $SHA1 =~ s/^$metatxt:\s*//;
 244
 245
 246 # write out result
 247 sub print_tag
 248 {
 249         my ($key, $uid) = @_;
 250         if (! defined $sigs->{$key}->{$uid}) {
 251                 warn "uid '$uid' not found on key $key\n";
 252                 return '(' . (' ' x @mykeys) . ')';
 253         }
 254         my $r = '(';
 255         foreach my $mykey (@mykeys) {
 256                 $r .= defined $sigs->{$key}->{$uid}->{$mykey} ? $sigs->{$key}->{$uid}->{$mykey} : ' ';
 257         }
 258         $r .= ')';
 259         return $r;
 260 }
 261
 262 print STDERR "Annotating $keytxt, writing into $outfile\n";
 263 open (TXT, $keytxt) or die ("Cannot open $keytxt\n");
 264 open (WRITE, '>'.$outfile) or die ("Cannot open $outfile for writing\n");
 265 while (<TXT>) {
 266         $_ = myfromrecode($_);
 267         if (/^MD5 Checksum:/ && defined $MD5) {
 268                 s/[_[:xdigit:]][_ [:xdigit:]]+_/$MD5/;
 269         }
 270         if (/^SHA1 Checksum:/ && defined $SHA1) {
 271                 s/[_[:xdigit:]][_ [:xdigit:]]+_/$SHA1/;
 272         }
 273         if ( m/^pub  +(?:\d+)[DR]\/([0-9A-F]{8}) [0-9]{4}-[0-9]{2}-[0-9]{2} *(.*)/ ) {
 274                 $key = $1;
 275                 $uid = $2;
 276                 #if ($uid) { # in gpg 1.2, the first uid is here
 277                 #       print WRITE print_tag($key, $uid) . " $_";
 278                 #       next;
 279                 #}
 280         }
 281         if ( m/^uid +(.*)$/ ) {
 282                 $uid = $1;
 283                 die "key is undefined" unless defined $key;
 284                 die "uid is undefined, key $key" unless defined $uid;
 285                 die "bad tag from $key | $uid" unless defined (print_tag($key, $uid));
 286                 print WRITE print_tag($key, $uid) . " $_";
 287                 next;
 288         }
 289         print WRITE;
 290 }
 291
 292 print WRITE "Legend:\n";
 293 foreach my $i (0 .. @mykeys - 1) {
 294         print WRITE '('. ' 'x$i . 'S' . ' 'x(@mykeys-$i-1) . ") signed with $mykeys[$i]\n";
 295 }
 296 close TXT;
 297
 298 __END__
 299
 300 =head1 NAME
 301
 302 B<gpgsigs> - annotate list of GnuPG keys with already done signatures
 303
 304 =head1 SYNOPSIS
 305
 306 B<gpgsigs> [-r] [-f I<charset>] [-t I<charset>] I<keyid>I<[>B<,>I<keyidI<[>B<,>I<...>I<]>>I<]> F<keytxt> [F<outfile>]
 307
 308 =head1 DESCRIPTION
 309
 310 B<gpgsigs> was written to assist the user in signing keys during a keysigning
 311 party. It takes as input a file containing keys in C<gpg --list-keys> format
 312 and prepends every line with a tag indicating if the user has already signed
 313 that uid. When the file contains C<MD5 Checksum:> or C<SHA1 Checksum:> lines
 314 and placeholders (C<__ __>), the checksum is inserted.
 315
 316 =head1 OPTIONS
 317
 318 =over
 319
 320 =item -r
 321
 322 Call I<gpg --recv-keys> before creating the output.
 323
 324 =item -f I<charset>
 325
 326 Convert F<keytxt> from I<charset>. The default is ISO-8859-1.
 327
 328 =item -t I<charset>
 329
 330 Convert UIDs to I<charset>. The default is derived from LC_ALL, LC_CTYPE, and
 331 LANG, and if all these are unset, the default is ISO-8859-1.
 332
 333 =item I<keyid>
 334
 335 Use this keyid (8 or 16 byte) for annotation. Multiple keyids can be separated
 336 by a comma (B<,>).
 337
 338 =item F<keytxt>
 339
 340 Read input from F<keytxt>.
 341
 342 =item F<outfile>
 343
 344 Write output to F<outfile>. Default is stdout.
 345
 346 =back
 347
 348 =head1 EXAMPLES
 349
 350 The following key signing parties are using B<gpgsigs>:
 351
 352 http://www.palfrader.org/ksp-lt2k4.html
 353
 354 http://www.palfrader.org/ksp-lt2k5.html
 355
 356 =head1 BUGS
 357
 358 B<GnuPG> is known to change its output format quite often. This version has
 359 been tested with gpg 1.2.5 and gpg 1.4.1. YMMV.
 360
 361 =head1 SEE ALSO
 362
 363 gpg(1), caff(1).
 364
 365 http://pgp-tools.alioth.debian.org/
 366
 367 =head1 AUTHORS AND COPYRIGHT
 368
 369 (c) 2004 Uli Martens <uli@youam.net>
 370
 371 (c) 2004, 2005 Peter Palfrader <peter@palfrader.org>
 372
 373 (c) 2004, 2005 Christoph Berg <cb@df7cb.de>
 374
 375 =head1 LICENSE
 376
 377 All rights reserved.
 378
 379 Redistribution and use in source and binary forms, with or without
 380 modification, are permitted provided that the following conditions
 381 are met:
 382
 383 1. Redistributions of source code must retain the above copyright
 384 notice, this list of conditions and the following disclaimer.
 385
 386 2. Redistributions in binary form must reproduce the above copyright
 387 notice, this list of conditions and the following disclaimer in the
 388 documentation and/or other materials provided with the distribution.
 389
 390 3. The name of the author may not be used to endorse or promote products
 391 derived from this software without specific prior written permission.
 392
 393 THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
 394 IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
 395 OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
 396 IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
 397 INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
 398 NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 399 DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 400 THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 401 (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
 402 THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.