sdformat/sdformat-6.2.0-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit cmake-utils
   7
   8 DESCRIPTION="Simulation Description Format (SDF) parser"
   9 HOMEPAGE="http://sdformat.org/"
  10 SRC_URI="http://osrf-distributions.s3.amazonaws.com/sdformat/releases/${P}.tar.bz2"
  11
  12 LICENSE="Apache-2.0"
  13 # subslot = libsdformat major
  14 SLOT="0/6"
  15 KEYWORDS="~amd64"
  16 IUSE=""
  17
  18 RDEPEND="
  19         >=dev-libs/urdfdom-1:=
  20         dev-libs/tinyxml
  21         dev-libs/boost:=
  22         sci-libs/ignition-math:4=
  23 "
  24 DEPEND="${RDEPEND}
  25         dev-lang/ruby:*
  26         virtual/pkgconfig
  27 "
  28 CMAKE_BUILD_TYPE=RelWithDebInfo
  29
  30 src_configure() {
  31         echo "set (CMAKE_C_FLAGS_ALL \"${CXXFLAGS} \${CMAKE_C_FLAGS_ALL}\")" > "${S}/cmake/HostCFlags.cmake"
  32         sed -i -e "s/LINK_FLAGS_RELWITHDEBINFO \" \"/LINK_FLAGS_RELWITHDEBINFO \" ${LDFLAGS} \"/" cmake/DefaultCFlags.cmake || die
  33         local mycmakeargs=(
  34                 "-DUSE_EXTERNAL_TINYXML=ON"
  35         )
  36         cmake-utils_src_configure
  37 }