sci-mathematics/cgal/cgal-4.2.ebuild

   1 # Distributed under the terms of the GNU General Public License v2
   2
   3 EAPI=4
   4
   5 CMAKE_BUILD_TYPE=Release
   6
   7 inherit base multilib cmake-utils
   8
   9 MY_P=CGAL-${PV}
  10 PID=32361
  11 DPID=32365
  12
  13 DESCRIPTION="C++ library for geometric algorithms and data structures"
  14 HOMEPAGE="http://www.cgal.org/ https://gforge.inria.fr/projects/cgal/"
  15 SRC_URI="
  16         http://gforge.inria.fr/frs/download.php/${PID}/${MY_P}.tar.xz
  17         doc? ( http://gforge.inria.fr/frs/download.php/${DPID}/${MY_P}-doc_html.tar.xz )"
  18
  19 LICENSE="LGPL-3 GPL-3 Boost-1.0"
  20 SLOT="0"
  21 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
  22 IUSE="doc examples +gmp mpfi qt4"
  23
  24 RDEPEND="
  25         dev-libs/boost
  26         dev-libs/mpfr
  27         sys-libs/zlib
  28         x11-libs/libX11
  29         virtual/glu
  30         virtual/opengl
  31         gmp? ( dev-libs/gmp[cxx] )
  32         qt4? (
  33                 dev-qt/qtgui:4
  34                 dev-qt/qtopengl:4 )
  35         mpfi? ( sci-libs/mpfi )"
  36 DEPEND="${RDEPEND}
  37         app-arch/xz-utils"
  38
  39 S="${WORKDIR}/${MY_P}"
  40
  41 DOCS="AUTHORS CHANGES* README"
  42
  43 src_prepare() {
  44         base_src_prepare
  45         sed \
  46                 -e '/install(FILES AUTHORS/d' \
  47                 -i CMakeLists.txt || die
  48 }
  49
  50 src_configure() {
  51         local mycmakeargs+=(
  52                 -DCGAL_INSTALL_LIB_DIR=$(get_libdir)
  53                 -DWITH_CGAL_Qt3=OFF
  54                 -DWITH_LEDA=OFF
  55                 $(cmake-utils_use_with gmp)
  56                 $(cmake-utils_use_with gmp GMPXX)
  57                 $(cmake-utils_use_with qt4 CGAL_Qt4)
  58                 $(cmake-utils_use_with mpfi)
  59         )
  60         cmake-utils_src_configure
  61 }
  62
  63 src_install() {
  64         cmake-utils_src_install
  65         use doc && dohtml -r "${WORKDIR}"/doc_html/cgal_manual/*
  66         if use examples; then
  67                 insinto /usr/share/doc/${PF}
  68                 doins -r examples demo
  69         fi
  70 }