media-gfx/ipe/ipe-7.1.3.ebuild

   1 # Distributed under the terms of the GNU General Public License v2
   2 # $Header: $
   3
   4 EAPI=4
   5 inherit eutils toolchain-funcs qt4-r2
   6
   7 DESCRIPTION="Drawing editor for creating figures in PDF or PS formats"
   8 HOMEPAGE="http://ipe7.sourceforge.net/"
   9 SRC_URI="mirror://sourceforge/ipe7/${PN}/7.1.0/${P}-src.tar.gz"
  10
  11 LICENSE="GPL-3"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="highprec"
  15
  16 RDEPEND="app-text/texlive-core
  17         dev-lang/lua
  18         media-libs/freetype:2
  19         x11-libs/cairo
  20         dev-qt/qtcore:4
  21         dev-qt/qtgui:4"
  22 DEPEND="${RDEPEND}
  23         virtual/pkgconfig"
  24
  25 S="${WORKDIR}/${P}/src"
  26 COMMONDIR=/usr/share/ipe/common
  27
  28 search_urw_fonts() {
  29         # colon-separated list of paths
  30         local texmfdist="$(kpsewhich -var-value=TEXMFDIST)"
  31         # according to TeX directory structure
  32         local urwdir=fonts/type1/urw
  33         # add colon as field separator
  34         local IFS="${IFS}:" dir
  35         for dir in ${texmfdist}; do
  36                 if [[ -d ${dir}/${urwdir} ]]; then
  37                         URWFONTDIR="${dir}/${urwdir}"
  38                         return 0
  39                 fi
  40         done
  41         return 1
  42 }
  43
  44 pkg_setup() {
  45         if search_urw_fonts; then
  46                 einfo "URW fonts found in ${URWFONTDIR}"
  47         else
  48                 ewarn "Could not find directory containing URW fonts"
  49                 ewarn "Ipe will not function properly without them."
  50         fi
  51 }
  52
  53 src_prepare() {
  54         sed -i \
  55                 -e 's/fpic/fPIC/' \
  56                 -e 's/moc-qt4/moc/' \
  57                 -e "s:\$(IPEPREFIX)/lib:\$(IPEPREFIX)/$(get_libdir):g" \
  58                 config.mak || die
  59         sed -i -e 's/install -s/install/' common.mak || die
  60
  61         if use highprec; then
  62                 einfo "Adding patch for higher output precision"
  63                 epatch "${FILESDIR}"/${PN}-outputprecision.patch
  64         fi
  65 }
  66
  67 src_compile() {
  68         emake \
  69                 CXX=$(tc-getCXX) \
  70                 IPEPREFIX="${EPREFIX}/usr" \
  71                 IPEDOCDIR="${EPREFIX}/usr/share/doc/${PF}/html"
  72 }
  73
  74 src_install() {
  75         emake install \
  76                 IPEPREFIX="${EPREFIX}/usr" \
  77                 IPEDOCDIR="${EPREFIX}/usr/share/doc/${PF}/html" \
  78                 INSTALL_ROOT="${ED}"
  79         dodoc ../{news,readme}.txt
  80         doicon ipe/icons/ipe.png
  81         make_desktop_entry ipe Ipe ipe
  82         # Link style sheets
  83         if [ -d $COMMONDIR/styles ]; then
  84                 einfo "Linking common style sheets from $COMMONDIR"
  85                 for f in $COMMONDIR/styles/*; do
  86                         einfo "  Linking ${f##*/}"
  87                         dosym $f usr/share/ipe/${PV}/styles/${f##*/}
  88                 done
  89
  90                 elog "Style sheets from $COMMONDIR/styles have been symlinked to"
  91                 elog "the style sheet directory of ${P}. If you add additional"
  92                 elog "style sheets later to $COMMONDIR/styles you may symlink"
  93                 elog "them by hand to '/usr/share/ipe/${PV}/styles/'."
  94         fi
  95 }