games-action/supertuxkart/supertuxkart-0.8.1.ebuild

   1 # Copyright 1999-2013 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/games-action/supertuxkart/supertuxkart-0.8.ebuild,v 1.8 2013/02/07 21:59:52 ulm Exp $
   4
   5 EAPI=2
   6 inherit cmake-utils eutils games
   7
   8 DESCRIPTION="A kart racing game starring Tux, the linux penguin (TuxKart fork)"
   9 HOMEPAGE="http://supertuxkart.sourceforge.net/"
  10 SRC_URI="mirror://sourceforge/supertuxkart/SuperTuxKart/${PV}/${P}-src.tar.bz2
  11         mirror://gentoo/${PN}.png"
  12
  13 LICENSE="GPL-3 CC-BY-SA-3.0 CC-BY-2.0 public-domain ZLIB"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~ppc ~x86"
  16 IUSE="debug"
  17
  18 # don't unbundle irrlicht and bullet
  19 # both are modified and system versions will break the game
  20 # http://sourceforge.net/tracker/?func=detail&aid=3454889&group_id=74339&atid=540679
  21
  22 # VERSION BUMP NOTICE: enet might be needed for supertuxkart-0.9
  23 RDEPEND="dev-libs/fribidi
  24         media-libs/freeglut
  25         media-libs/libpng:0
  26         media-libs/libvorbis
  27         media-libs/openal
  28         net-misc/curl
  29         sys-libs/zlib
  30         virtual/glu
  31         virtual/jpeg
  32         virtual/libintl
  33         virtual/opengl
  34         x11-libs/libX11
  35         x11-libs/libXxf86vm"
  36 DEPEND="${RDEPEND}
  37         sys-devel/gettext
  38         virtual/pkgconfig"
  39
  40 S=${WORKDIR}/SuperTuxKart-${PV}
  41
  42 src_prepare() {
  43         epatch "${FILESDIR}"/${P}-{gentoo,irrlicht}.patch
  44
  45         # inconsistent handling of debug definition
  46         # avoid using Debug build type
  47         if use debug ; then
  48                 sed -i \
  49                         -e 's/add_definitions(-DNDEBUG)/add_definitions(-DDEBUG)/' \
  50                         CMakeLists.txt || die
  51         fi
  52 }
  53
  54 src_configure() {
  55         local mycmakeargs=(
  56                 -DSTK_INSTALL_BINARY_DIR="${GAMES_BINDIR}"
  57                 -DSTK_INSTALL_DATA_DIR="${GAMES_DATADIR}"/${PN}
  58         )
  59
  60         cmake-utils_src_configure
  61 }
  62
  63 src_compile() {
  64         # build bundled irrlicht
  65         NDEBUG=1 emake -C lib/irrlicht/source/Irrlicht
  66
  67         cmake-utils_src_compile
  68 }
  69
  70 src_install() {
  71         cmake-utils_src_install
  72         doicon "${DISTDIR}"/${PN}.png
  73         dodoc AUTHORS ChangeLog README TODO
  74         prepgamesdirs
  75 }