app-admin/conky/conky-1.10.8-r5.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cmake-utils linux-info readme.gentoo-r1
   7
   8 DESCRIPTION="An advanced, highly configurable system monitor for X"
   9 HOMEPAGE="https://github.com/brndnmtthws/conky"
  10 SRC_URI="https://github.com/brndnmtthws/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="GPL-3 BSD LGPL-2.1 MIT"
  13 SLOT="0"
  14 KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
  15 IUSE="apcupsd cmus curl eve hddtemp ical iconv imlib iostats ipv6 irc
  16         lua-cairo lua-imlib lua-rsvg math moc mpd mysql nano-syntax ncurses
  17         nvidia +portmon pulseaudio rss systemd thinkpad truetype vim-syntax
  18         weather-metar webserver wifi X xmms2"
  19
  20 COMMON_DEPEND="
  21         X? (
  22                 imlib? ( media-libs/imlib2[X] )
  23                 lua-cairo? ( >=dev-lua/toluapp-1.0.93 x11-libs/cairo[X] )
  24                 lua-imlib? ( >=dev-lua/toluapp-1.0.93 media-libs/imlib2[X] )
  25                 lua-rsvg? ( >=dev-lua/toluapp-1.0.93 gnome-base/librsvg )
  26                 nvidia? ( x11-drivers/nvidia-drivers[tools,static-libs] )
  27                 truetype? ( x11-libs/libXft >=media-libs/freetype-2 )
  28                 x11-libs/libX11
  29                 x11-libs/libXdamage
  30                 x11-libs/libXinerama
  31                 x11-libs/libXfixes
  32                 x11-libs/libXext
  33                 xmms2? ( media-sound/xmms2 )
  34         )
  35         cmus? ( media-sound/cmus )
  36         curl? ( net-misc/curl )
  37         eve? ( net-misc/curl dev-libs/libxml2 )
  38         ical? ( dev-libs/libical )
  39         iconv? ( virtual/libiconv )
  40         irc? ( net-libs/libircclient )
  41         mysql? ( dev-db/mysql-connector-c )
  42         ncurses? ( sys-libs/ncurses:= )
  43         pulseaudio? ( media-sound/pulseaudio )
  44         rss? ( dev-libs/libxml2 net-misc/curl dev-libs/glib:2 )
  45         systemd? ( sys-apps/systemd )
  46         wifi? ( net-wireless/wireless-tools )
  47         weather-metar? ( net-misc/curl )
  48         webserver? ( net-libs/libmicrohttpd )
  49         >=dev-lang/lua-5.1.4-r8
  50 "
  51 RDEPEND="
  52         ${COMMON_DEPEND}
  53         apcupsd? ( sys-power/apcupsd )
  54         hddtemp? ( app-admin/hddtemp )
  55         moc? ( media-sound/moc )
  56         nano-syntax? ( app-editors/nano )
  57         vim-syntax? ( || ( app-editors/vim app-editors/gvim ) )
  58 "
  59 DEPEND="
  60         ${COMMON_DEPEND}
  61         app-text/docbook2X
  62 "
  63
  64 CONFIG_CHECK=~IPV6
  65
  66 DOCS=( README.md TODO ChangeLog NEWS AUTHORS )
  67
  68 PATCHES=(
  69         "${FILESDIR}"/${P}-use-pkgconfig.patch
  70         "${FILESDIR}"/${P}-libical-3.patch
  71 )
  72
  73 DISABLE_AUTOFORMATTING="yes"
  74 DOC_CONTENTS="You can find sample configurations at ${ROOT}/usr/share/doc/${PF}.
  75 To customize, copy to ${XDG_CONFIG_HOME}/conky/conky.conf
  76 and edit it to your liking.
  77
  78 There are pretty html docs available at the conky homepage
  79 or in ${ROOT}/usr/share/doc/${PF}/html.
  80
  81 Also see https://wiki.gentoo.org/wiki/Conky/HOWTO"
  82
  83 pkg_setup() {
  84         use ipv6 && linux-info_pkg_setup
  85 }
  86
  87 src_prepare() {
  88         cmake-utils_src_prepare
  89
  90         sed -i -e "s|find_program(APP_MAN man)|set(APP_MAN $(which man) CACHE FILEPATH MAN_BINARY)|" \
  91                 cmake/ConkyPlatformChecks.cmake || die
  92 }
  93
  94 src_configure() {
  95         local mycmakeargs
  96
  97         if use X; then
  98                 mycmakeargs=(
  99                         -DBUILD_X11=ON
 100                         -DOWN_WINDOW=ON
 101                         -DBUILD_XDAMAGE=ON
 102                         -DBUILD_XINERAMA=ON
 103                         -DBUILD_XDBE=ON
 104                         -DBUILD_XFT=$(usex truetype)
 105                         -DBUILD_IMLIB2=$(usex imlib)
 106                         -DBUILD_XSHAPE=ON
 107                         -DBUILD_ARGB=ON
 108                         -DBUILD_LUA_CAIRO=$(usex lua-cairo)
 109                         -DBUILD_LUA_IMLIB2=$(usex lua-imlib)
 110                         -DBUILD_LUA_RSVG=$(usex lua-rsvg)
 111                         -DBUILD_NVIDIA=$(usex nvidia)
 112                         -DBUILD_XMMS2=$(usex xmms2)
 113                 )
 114         else
 115                 mycmakeargs=(
 116                         -DBUILD_X11=OFF
 117                         -DBUILD_NVIDIA=OFF
 118                         -DBUILD_LUA_CAIRO=OFF
 119                         -DBUILD_LUA_IMLIB2=OFF
 120                         -DBUILD_LUA_RSVG=OFF
 121                         -DBUILD_XMMS2=OFF
 122                 )
 123         fi
 124
 125         mycmakeargs+=(
 126                 -DBUILD_APCUPSD=$(usex apcupsd)
 127                 -DBUILD_CMUS=$(usex cmus)
 128                 -DBUILD_CURL=$(usex curl)
 129                 -DBUILD_EVE=$(usex eve)
 130                 -DBUILD_HDDTEMP=$(usex hddtemp)
 131                 -DBUILD_IOSTATS=$(usex iostats)
 132                 -DBUILD_ICAL=$(usex ical)
 133                 -DBUILD_ICONV=$(usex iconv)
 134                 -DBUILD_IPV6=$(usex ipv6)
 135                 -DBUILD_IRC=$(usex irc)
 136                 -DBUILD_MATH=$(usex math)
 137                 -DBUILD_MOC=$(usex moc)
 138                 -DBUILD_MPD=$(usex mpd)
 139                 -DBUILD_MYSQL=$(usex mysql)
 140                 -DBUILD_NCURSES=$(usex ncurses)
 141                 -DBUILD_PORT_MONITORS=$(usex portmon)
 142                 -DBUILD_PULSEAUDIO=$(usex pulseaudio)
 143                 -DBUILD_RSS=$(usex rss)
 144                 -DBUILD_JOURNAL=$(usex systemd)
 145                 -DBUILD_IBM=$(usex thinkpad)
 146                 -DBUILD_HTTP=$(usex webserver)
 147                 -DBUILD_WEATHER_METAR=$(usex weather-metar)
 148                 -DBUILD_WLAN=$(usex wifi)
 149                 -DBUILD_BUILTIN_CONFIG=ON
 150                 -DBUILD_OLD_CONFIG=ON
 151                 -DBUILD_I18N=ON
 152                 -DMAINTAINER_MODE=ON
 153                 -DRELEASE=ON
 154                 -DBUILD_AUDACIOUS=OFF
 155                 -DBUILD_BMPX=OFF
 156                 -DDOC_PATH=/usr/share/doc/${PF}
 157         )
 158
 159         cmake-utils_src_configure
 160 }
 161
 162 src_install() {
 163         cmake-utils_src_install
 164
 165         if use vim-syntax; then
 166                 insinto /usr/share/vim/vimfiles/ftdetect
 167                 doins "${S}"/extras/vim/ftdetect/conkyrc.vim
 168
 169                 insinto /usr/share/vim/vimfiles/syntax
 170                 doins "${S}"/extras/vim/syntax/conkyrc.vim
 171         fi
 172
 173         if use nano-syntax; then
 174                 insinto /usr/share/nano/
 175                 doins "${S}"/extras/nano/conky.nanorc
 176         fi
 177
 178         readme.gentoo_create_doc
 179 }
 180
 181 pkg_postinst() {
 182         readme.gentoo_print_elog
 183 }