From 9629ffd7e083dd418851697b0fb5bf1c2f67b85d Mon Sep 17 00:00:00 2001
From: Stefan Huber <shuber@sthu.org>
Date: Wed, 3 Jun 2026 13:03:47 +0200
Subject: [PATCH] media-gfx/ipe: Add ipe-9999

---
 media-gfx/ipe/Manifest        |   1 +
 media-gfx/ipe/ipe-9999.ebuild | 112 ++++++++++++++++++++++++++++++++++
 2 files changed, 113 insertions(+)
 create mode 100644 media-gfx/ipe/ipe-9999.ebuild

diff --git a/media-gfx/ipe/Manifest b/media-gfx/ipe/Manifest
index 35ffb25..d3d6ed5 100644
--- a/media-gfx/ipe/Manifest
+++ b/media-gfx/ipe/Manifest
@@ -7,4 +7,5 @@ EBUILD ipe-7.2.25.ebuild 2775 BLAKE2B 52e1b504fc9a00c939c190eb81a9b6ffd25d265449
 EBUILD ipe-7.2.28.ebuild 2577 BLAKE2B d051101823686ec97aa48a07be642aecb33ed81ec80f21cc2afe9b3b19e4d9c4982b951d2f58ed885f9c9a9722b3b6f18d5539137dae471de74c3de068af30e2 SHA512 a0c150716181fbb54e1f1c9411f02597fe16be96e501906961ced5289936af22657073a9608805494683fa5d0e4c065fdc1efba5cbb1167d3393754ccc5e583a
 EBUILD ipe-7.2.29.ebuild 2577 BLAKE2B d051101823686ec97aa48a07be642aecb33ed81ec80f21cc2afe9b3b19e4d9c4982b951d2f58ed885f9c9a9722b3b6f18d5539137dae471de74c3de068af30e2 SHA512 a0c150716181fbb54e1f1c9411f02597fe16be96e501906961ced5289936af22657073a9608805494683fa5d0e4c065fdc1efba5cbb1167d3393754ccc5e583a
 EBUILD ipe-7.2.30.ebuild 2577 BLAKE2B d051101823686ec97aa48a07be642aecb33ed81ec80f21cc2afe9b3b19e4d9c4982b951d2f58ed885f9c9a9722b3b6f18d5539137dae471de74c3de068af30e2 SHA512 a0c150716181fbb54e1f1c9411f02597fe16be96e501906961ced5289936af22657073a9608805494683fa5d0e4c065fdc1efba5cbb1167d3393754ccc5e583a
+EBUILD ipe-9999.ebuild 2590 BLAKE2B c9b3934d66c3fb9dc9475b9c63962d1e6eea2c7a400ad3e9a977b886c36bf9d07a382b194fb6f2cee5113cae5290af1069cc4757adc65c5dde8f95436eb4521f SHA512 91a4224bf6f8e5d0f6e46a9b945a5748f3dc54f08ad6c7399f3cad960956b487ce34853e2d61cb6f878d6b748f5f374735fa2c23368503ed83c4d88048a3d5d4
 MISC metadata.xml 243 BLAKE2B 889d08efb220a9fb8457500f5f3c33c8c737616995e19fa8b621ced4bc9d380d016413d098d4d09925c679cd23f7fbd75e495424fe6ed809a9e873014caae682 SHA512 f9051a65d7e11d7abd1b9568dbbf8be84a6ae68eb994b0c22d57dff5620047d5ad5a324057a5cf4cec10837d16024e5f21a8cf5f1a6247807f62931839eb73bc
diff --git a/media-gfx/ipe/ipe-9999.ebuild b/media-gfx/ipe/ipe-9999.ebuild
new file mode 100644
index 0000000..79ada6f
--- /dev/null
+++ b/media-gfx/ipe/ipe-9999.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-3 )
+inherit lua-single toolchain-funcs
+
+DESCRIPTION="Drawing editor for creating figures in PDF or PS formats"
+HOMEPAGE="http://ipe.otfried.org"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/otfried/${PN}.git"
+else
+	KEYWORDS="~amd64"
+	SRC_URI=" https://github.com/otfried/ipe/archive/refs/tags/v${PV}.tar.gz"
+fi
+
+
+RESTRICT="mirror"
+
+LICENSE="GPL-3"
+SLOT="0"
+
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="
+	app-text/texlive-core
+	dev-qt/qtbase:6[widgets,gui]
+	dev-qt/qtsvg:6
+	media-libs/freetype:2
+	media-libs/libjpeg-turbo
+	media-libs/libpng
+	media-libs/libspiro
+	sci-libs/gsl
+	sys-libs/zlib
+	x11-libs/cairo
+	"
+DEPEND="${RDEPEND}
+	${LUA_DEPS}"
+
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${P}/src"
+COMMONDIR=/usr/share/ipe/common
+
+search_urw_fonts() {
+	# colon-separated list of paths
+	local texmfdist="$(kpsewhich -var-value=TEXMFDIST)"
+	# according to TeX directory structure
+	local urwdir=fonts/type1/urw
+	# add colon as field separator
+	local IFS="${IFS}:" dir
+	for dir in ${texmfdist}; do
+		if [[ -d ${dir}/${urwdir} ]]; then
+			URWFONTDIR="${dir}/${urwdir}"
+			return 0
+		fi
+	done
+	return 1
+}
+
+src_prepare() {
+	sed -i \
+		-e 's/fpic/fPIC/' \
+		-e 's_/usr/lib/qt6/libexec/moc_/usr/lib64/qt6/libexec/moc_' \
+		-e "s:\$(IPEPREFIX)/lib:\$(IPEPREFIX)/$(get_libdir):g" \
+		config.mak || die
+	sed -i -e 's/install -s/install/' common.mak || die
+
+	eapply_user
+}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	if search_urw_fonts; then
+		einfo "URW fonts found in ${URWFONTDIR}"
+	else
+		ewarn "Could not find directory containing URW fonts"
+		ewarn "Ipe will not function properly without them."
+	fi
+}
+
+src_compile() {
+	emake \
+		CXX=$(tc-getCXX) \
+		IPEPREFIX="${EPREFIX}/usr" \
+		IPEDOCDIR="${EPREFIX}/usr/share/doc/${PF}/html"
+}
+
+src_install() {
+	emake install \
+		IPEPREFIX="${EPREFIX}/usr" \
+		IPEDOCDIR="${EPREFIX}/usr/share/doc/${PF}/html" \
+		INSTALL_ROOT="${ED}" \
+		LUA_VERSION="$(lua_get_version)"
+	make_desktop_entry ipe Ipe ipe
+	# Link style sheets
+	if [ -d $COMMONDIR/styles ]; then
+		einfo "Linking common style sheets from $COMMONDIR"
+		for f in $COMMONDIR/styles/*; do
+			einfo "  Linking ${f##*/}"
+			dosym $f usr/share/ipe/${PV}/styles/${f##*/}
+		done
+
+		elog "Style sheets from $COMMONDIR/styles have been symlinked to"
+		elog "the style sheet directory of ${P}. If you add additional"
+		elog "style sheets later to $COMMONDIR/styles you may symlink"
+		elog "them by hand to '/usr/share/ipe/${PV}/styles/'."
+	fi
+}
-- 
2.39.5